### 第15课 红外遥控智能车
#### 15.1 项目介绍：
在之前的课程中，我们已经学习了智能车上各个传感器、模块以及扩展板的使用方法。今天，我们将把这些知识结合起来，制作一个红外遥控智能车。
还记得在“传感器项目第六课”中，我们测试出了红外遥控器上每个按键对应的唯一“身份证号”（也就是键值）吗？在本节课中，我们将编写程序，让Arduino读取这些键值。当你按下遥控器上的不同按键时，智能车就会执行前进、后退、左转、右转或停止的动作。同时，为了让互动更有趣，小车前方的 8x16 LED点阵屏 还会实时显示当前运动状态的图标（如箭头或文字）。
#### 15.2 控制逻辑：
我们需要建立按键与小车动作之间的对应关系。具体逻辑如下表所示：
| 按键图示 | 键值 (十六进制) | 小车状态 |点阵屏显示内容 |
| :--: | :--: | :--: | :--: |
| | FF629D | 前进 | 向上箭头 ↑ |
| | FFA857 | 后退 | 向下箭头 ↓ |
| | FF22DD | 左转 | 向左箭头 ← |
| | FFC23D | 右转 | 向右箭头 → |
| | FF02FD | 停止 | "STOP" 字样 |
#### 15.3 项目组件：
| 组装好的智能车(未插上蓝牙模块) *1 |USB线 *1 | 5号(1.5V)电池 *6（电池自备） |红外遥控器 *1|
| --- | --- | --- |
|  | |  | |
#### 15.4 接线图：
⚠️ 特别注意：4WD智能车已经组装好了，这里不需要把红外接收模块、8x16 LED点阵模块和4个电机拆下来又重新组装和接线，这里再次提供接线图，是为了方便您编写代码！
| 红外接收模块 | 电机驱动扩展板 |
| :--: | :--: |
| GND | G |
| VCC | 5V |
| S | A1 |
| 8x16 LED点阵模块 | 电机驱动扩展板 |
| :--: | :--: |
| GND | G |
| VCC | 5V |
| SDA | A4 |
| SCL | A5 |
| 电机 | 电机驱动扩展板 |
| :--: | :--: |
| 左侧电机（M1） | B2 |
| 左侧电机（M2） | B1 |
| 右侧电机（M3） | A1 |
| 右侧电机（M4） | A2 |
⚠️ **特别注意：**
- 接线时请确保电源断开(拔掉Arduino主控板上的USB线或将电机驱动扩展板上的拨码开关拨到 “**OFF**” 端)，避免短路。
- 电源连接：电池盒电源接到电机驱动扩展板的 BAT 接口（注意正负极不要接反），端口正反面，请勿反插，否则会损坏端口。
- 电池正负极切勿接反，否则可能烧毁电机驱动扩展板。
#### 15.5 示例代码：
⚠️ **重要提示：**
- 1\. 你需要安装 `IRremote` 库才能编译此代码。
- 2\. **上传示例代码前，请务必拔掉蓝牙模块！ 因为蓝牙模块也占用Arduino的串口通信（TX/RX），如果不拔掉，示例代码上传会失败。**
```cpp
/*
keyes 4WD 多功能智能车
课程 15
遥控机器人
http://www.keyes-robot.com
*/
#include
#define RECV_PIN A1 // 红外接收引脚 A1
#define SCL_PIN A5 // 时钟引脚 A5
#define SDA_PIN A4 // 数据引脚 A4
#define MA 2 // 电机M3,M4方向控制引脚 D2
#define PWMA 6 // 电机M3,M4速度控制引脚 D6
#define MB 4 // 电机M1,M2方向控制引脚 D4
#define PWMB 5 // 电机M1,M2速度控制引脚 D5
IRrecv irrecv(RECV_PIN);
decode_results results; // 声明红外接收结果变量
int irVal;
// 图案数据数组，可自行计算或使用取模工具获得
unsigned char start01[] = {0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80, 0x80, 0x40, 0x20, 0x10, 0x08, 0x04, 0x02, 0x01};
unsigned char front[] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x24, 0x12, 0x09, 0x12, 0x24, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
unsigned char back01[] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x24, 0x48, 0x90, 0x48, 0x24, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
unsigned char left[] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x44, 0x28, 0x10, 0x44, 0x28, 0x10, 0x44, 0x28, 0x10, 0x00};
unsigned char right[] = {0x00, 0x10, 0x28, 0x44, 0x10, 0x28, 0x44, 0x10, 0x28, 0x44, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
unsigned char stop01[] = {0x2E, 0x2A, 0x3A, 0x00, 0x02, 0x3E, 0x02, 0x00, 0x3E, 0x22, 0x3E, 0x00, 0x3E, 0x0A, 0x0E, 0x00};
unsigned char clear[] = {0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
/* 功能：小车前进 */
void advance() {
digitalWrite(MA, HIGH); // 电机A正转
analogWrite(PWMA, 200); // 电机A速度为200
digitalWrite(MB, HIGH); // 电机B正转
analogWrite(PWMB, 200); // 电机B速度为200
}
/* 功能：小车后退 */
void back() {
digitalWrite(MA, LOW); // 电机A反转
analogWrite(PWMA, 200); // 电机A速度为200
digitalWrite(MB, LOW); // 电机B反转
analogWrite(PWMB, 200); // 电机B速度为200
}
/* 功能：小车左转 */
void turnLeft() {
digitalWrite(MA, HIGH); // 电机A正转
analogWrite(PWMA, 200); // 电机A速度为200
digitalWrite(MB, LOW); // 电机B反转
analogWrite(PWMB, 200); // 电机B速度为200
}
/* 功能：小车右转 */
void turnRight() {
digitalWrite(MA, LOW); // 电机A反转
analogWrite(PWMA, 200); // 电机A速度为200
digitalWrite(MB, HIGH); // 电机B正转
analogWrite(PWMB, 200); // 电机B速度为200
}
/* 功能：小车停止 */
void stopCar() {
analogWrite(PWMA, 0); // 电机A速度为0
analogWrite(PWMB, 0); // 电机B速度为0
}
/* 功能：初始化设置 */
void setup() {
Serial.begin(9600); // 设置串口波特率为9600
pinMode(MA, OUTPUT); // 配置电机方向引脚为输出
pinMode(PWMA, OUTPUT); // 配置电机速度引脚为输出
pinMode(MB, OUTPUT);
pinMode(PWMB, OUTPUT);
pinMode(SCL_PIN, OUTPUT); // 配置I2C时钟引脚为输出
pinMode(SDA_PIN, OUTPUT); // 配置I2C数据引脚为输出
irrecv.enableIRIn(); // 启用红外接收
matrixDisplay(clear); // 点阵屏清屏
matrixDisplay(start01); // 显示启动图案
}
/* 功能：主循环，处理红外遥控信号 */
void loop() {
if (irrecv.decode(&results)) { // 判断是否接收到红外信号
irVal = results.value;
Serial.println(irVal, HEX); // 串口打印接收到的红外码（十六进制）
switch (irVal) {
case 0xFF629D:
advance();
matrixDisplay(front);
break;
case 0xFFA857:
back();
matrixDisplay(back01);
break;
case 0xFF22DD:
turnLeft();
matrixDisplay(left);
break;
case 0xFFC23D:
turnRight();
matrixDisplay(right);
break;
case 0xFF02FD:
stopCar();
matrixDisplay(stop01);
break;
}
irrecv.resume(); // 准备接收下一个红外信号
}
}
/* 功能：点阵屏显示图案 */
void matrixDisplay(unsigned char matrixValue[]) {
IICStart(); // 发送开始条件
IICSend(0xC0); // 选择点阵屏地址
for (int i = 0; i < 16; i++) { // 发送16字节图案数据
IICSend(matrixValue[i]);
}
IICEnd(); // 发送结束条件
IICStart();
IICSend(0x8A); // 显示控制，脉宽4/16
IICEnd();
}
/* 功能：I2C开始信号 */
void IICStart() {
digitalWrite(SCL_PIN, HIGH);
delayMicroseconds(3);
digitalWrite(SDA_PIN, HIGH);
delayMicroseconds(3);
digitalWrite(SDA_PIN, LOW);
delayMicroseconds(3);
}
/* 功能：I2C发送一个字节数据 */
void IICSend(unsigned char sendData) {
for (char i = 0; i < 8; i++) { // 逐位发送8位数据
digitalWrite(SCL_PIN, LOW); // 拉低时钟，准备改变数据线状态
delayMicroseconds(3);
if (sendData & 0x01) { // 判断最低位是1还是0
digitalWrite(SDA_PIN, HIGH);
} else {
digitalWrite(SDA_PIN, LOW);
}
delayMicroseconds(3);
digitalWrite(SCL_PIN, HIGH); // 拉高时钟，完成数据传输
delayMicroseconds(3);
sendData = sendData >> 1; // 右移一位，准备发送下一位
}
}
/* 功能：I2C结束信号 */
void IICEnd() {
digitalWrite(SCL_PIN, LOW);
delayMicroseconds(3);
digitalWrite(SDA_PIN, LOW);
delayMicroseconds(3);
digitalWrite(SCL_PIN, HIGH);
delayMicroseconds(3);
digitalWrite(SDA_PIN, HIGH);
delayMicroseconds(3);
}
```
#### 15.6 项目结果：
⚠️ **重要提示：**
- **上传示例代码前，请务必拔掉蓝牙模块！ 因为蓝牙模块也占用Arduino的串口通信（TX/RX），如果不拔掉，示例代码上传会失败。**
外接电源，将电机驱动扩展板上的拨码开关拨到 “**OFF**” 端。选择好正确的开发板板型（Arduino Uno）和 适当的串口端口（COMxx），然后单击  按钮上传示例代码至Arduino控制板。
- 打开电源：将电机驱动扩展板上的拨码开关拨到 “**ON**” 端。
- 打开红外遥控器，对准4WD智能车上的红外接收头，按下相应的按键。
- 按下  键，4WD智能车前进，8x16 LED点阵屏显示向上箭头。
- 按下  键，4WD智能车后退，8x16 LED点阵屏显示向下箭头。
- 按下  键，4WD智能车向左转，8x16 LED点阵屏显示向左箭头。
- 按下  键，4WD智能车向右转，8x16 LED点阵屏显示向右箭头。
- 按下  键，4WD智能车停止，8x16 LED点阵屏显示 “STOP” 字样。
#### 15.7 常见问题排查：
- 4WD智能车不动？
- 检查电池是否有电，拨码开关是否打开，电机接线是否牢固。
- 遥控没反应？
- 检查红外接收头接线是否正确（G/V/S），确保红外遥控器电池有电，且对准了接收头。可以通过串口监视器查看是否有键值打印出来。